Konfigurasi eBGP Peering dengan Loopback Peering di Mikrotik - Lab selanjutnya adalah konfigurasi external BGP dengan peering ke loopback interface. Langkah-langkahnya sama seperti dengan peering iBGP Loopback Interface. Perbedaanya hanya AS-Number dan opsi Multihop pada saat peering.Konfigurasi R1
/interface bridge
add name=lo0
add name=lo1
/routing bgp instance
set default as=1101 router-id=1.1.1.1
/routing ospf instance
set [ find default=yes ] router-id=11.11.11.11
/ip address
add address=10.1.1.1/30 interface=ether1 network=10.1.1.0
add address=10.1.1.10/30 interface=ether2 network=10.1.1.8
add address=192.168.1.1/24 interface=lo0 network=192.168.1.0
add address=1.1.1.1 interface=lo1 network=1.1.1.1
/routing bgp network
add network=192.168.1.0/24 synchronize=no
/routing bgp peer
add multihop=yes name=TO-R2 remote-address=2.2.2.2 remote-as=2202 ttl=default \
update-source=lo1
add multihop=yes name=TO-R3 remote-address=3.3.3.3 remote-as=3303 ttl=default \
update-source=lo1
/routing ospf network
add area=backbone network=10.1.1.0/30
add area=backbone network=10.1.1.8/30
add area=backbone network=1.1.1.1/32
/system identity
set name=R1
Langkah pertama adalah membuat interface loopback. lo0 akan digunakan untuk advertise network dan lo1 digunakan untuk peering. Membuat loopback cukup dengan membuat interface bridge.
Konfigurasi IP Address untuk masing-masing network sesuai topologi diatas.
Setelah antar physical IP Address saling terhubung, selanjutnya adalah melakukan konfigurasi Routing Dynamic OSPF. Routing ini bertujuan untuk menghubungkan antara interface loopback yang akan digunakan untuk peering disemua router atau dalam hal ini lo1.
Setelah antar loopback lo1 saling terhubung dibuktikan dengan saling ping interface lo1 antar router, dilanjutkan dengan membuat intance routing BGP. Dalam membuat instance, cukup definisikan AS-Number dari Router dan Router-ID.
Kemudian agar setiap router dapat saling terhubung, kita lakukan peering. Peering kali ini menggunakan interface loopback yang sudah terhubung menggunakan dynamic routing OSPF tadi. Sebagai contoh R1, lakukan peering ke R2 dan R3. Contoh peering ke R2, maka isi Remote-Address 2.2.2.2 dimana 2.2.2.2 merupakan loopback interface dari Router2, dan remote-as dari R2 yakni 2202.
/routing bgp peer
add multihop=yes name=TO-R2 remote-address=2.2.2.2 remote-as=2202 ttl=default \
update-source=lo1
add multihop=yes name=TO-R3 remote-address=3.3.3.3 remote-as=3303 ttl=default \
update-source=lo1
Jika remote-peer atau target peering ini melewati router dengan AS-Number yang berbeda, maka opsi multihop=yes adalah wajib. Opsi ini biasanya digunakan jika remote-peer atau router yang akan dipeering, tidak bertetangga langsung, atau istilahnya more than one hop away.
Setelah berhasil melakukan peering, selanjutnya tinggal melakukan advertise network. Jika R1 maka network yang diadvertise sesuai topologi diatas adalah 192.168.1.0/24.
Untuk R2 dan R3 konfigurasi sama, tinggal menyesuaikan pada topologi diatas.
Konfigurasi R2
/interface bridge
add name=lo0
add name=lo1
/routing bgp instance
set default as=2202 router-id=2.2.2.2
/routing ospf instance
set [ find default=yes ] router-id=22.22.22.22
/ip address
add address=10.1.1.2/30 interface=ether1 network=10.1.1.0
add address=10.1.1.5/30 interface=ether2 network=10.1.1.4
add address=192.168.2.1/24 interface=lo0 network=192.168.2.0
add address=2.2.2.2 interface=lo1 network=2.2.2.2
/routing bgp network
add network=192.168.2.0/24 synchronize=no
/routing bgp peer
add multihop=yes name=TO-R1 remote-address=1.1.1.1 remote-as=1101 ttl=default \
update-source=lo1
add multihop=yes name=TO-R3 remote-address=3.3.3.3 remote-as=3303 ttl=default \
update-source=lo1
/routing ospf network
add area=backbone network=10.1.1.0/30
add area=backbone network=10.1.1.4/30
add area=backbone network=2.2.2.2/32
/system identity
set name=R2
Konfigurasi R3
/interface bridge
add name=lo0
add name=lo1
/routing bgp instance
set default as=3303 router-id=3.3.3.3
/routing ospf instance
set [ find default=yes ] router-id=33.33.33.33
/ip address
add address=10.1.1.6/30 interface=ether1 network=10.1.1.4
add address=10.1.1.9/30 interface=ether2 network=10.1.1.8
add address=192.168.3.1/24 interface=lo0 network=192.168.3.0
add address=3.3.3.3 interface=lo1 network=3.3.3.3
/routing bgp network
add network=192.168.3.0/24 synchronize=no
/routing bgp peer
add multihop=yes name=TO-R2 remote-address=2.2.2.2 remote-as=2202 ttl=default \
update-source=lo1
add multihop=yes name=TO-R1 remote-address=1.1.1.1 remote-as=1101 ttl=default \
update-source=lo1
/routing ospf network
add area=backbone network=10.1.1.4/30
add area=backbone network=10.1.1.8/30
add area=backbone network=3.3.3.3/32
/system identity
set name=R3
Pengujian
Pengujian dilakukan dengan melihat beberapa parameter seperti tabel routing, informasi peering dan network yang berhasil di advertise.Kita akan coba cek di R2
Seperti yang kita bisa lihat, untuk menjangkau network 192.168.3.0/24, R2 menggunakan routing external BGP ditandari dengan distance 20,dimana 20 adalah Administrative Distance untuk eBGP, melalui 3.3.3.3 dimana 3.3.3.3 ini dijangkau dengan menggunakan IP 10.1.1.6 di ether2 R3.
Opsi multihop diatas bisa dibuktikan sebagai contoh jika link antara R2 dan R3 putus. Sebagai contoh link tersebut dilakukan suspend
Saat link putus, maka link otomatis akan berpindah menggunakan interface ether1 dimana intersface tersebut mengarah ke R1. Jika opsi multihop tidak di enable, maka R1 tidak bisa peering ke R2.
[admin@R1] > routing bgp peer print detail
Flags: X - disabled, E - established
0 E name="TO-R2" instance=default remote-address=2.2.2.2 remote-as=2202
tcp-md5-key="" nexthop-choice=default multihop=yes route-reflect=no
hold-time=3m ttl=default in-filter="" out-filter="" address-families=ip
update-source=lo1 default-originate=never remove-private-as=no
as-override=no passive=no use-bfd=no
1 E name="TO-R3" instance=default remote-address=3.3.3.3 remote-as=3303
tcp-md5-key="" nexthop-choice=default multihop=yes route-reflect=no
hold-time=3m ttl=default in-filter="" out-filter="" address-families=ip
update-source=lo1 default-originate=never remove-private-as=no
as-override=no passive=no use-bfd=no
[admin@R1] > routing bgp advertisements pr
PEER PREFIX NEXTHOP AS-PATH ORIGIN LOCAL-PREF
TO-R2 192.168.1.0/24 1.1.1.1 igp
TO-R2 192.168.3.0/24 1.1.1.1 3303 igp
TO-R3 192.168.2.0/24 1.1.1.1 2202 igp
TO-R3 192.168.1.0/24 1.1.1.1 igp
[admin@R1] >
0 comments:
Post a Comment